;; 
	;; Modified Grumpy's 3 bar patch (5/23/2006)
	;; 
	ldab	#0xCB		; #0x87 load reg_b with 0xCB (203d)
	mul			; multiply filtered MAP A/D (0x00-0xFF) by 0xCB (203d), result is xx.yy
	subd	#0x0190		; (FILT_MAP_A2D * 203d) - 400d
	bcc	LF57B		; br if (FILT_MAP_A2D * 203d) is greater than 400d
	clra			; clr result if less than 400d, clr if MAP A/D is less than 0x02 (3d) (for 2-bar)
	clrb			; clr result if less than 400d, clr if MAP A/D is less than 0x01 (2d) (for 3-bar)
LF57B:	lsld			; 2 * [(FILT_MAP_A2D * 203d) - 400d]
	bcs	LF581		; br if overflow
	lsld			; 2 * {2 * [(FILT_MAP_A2D * 203d) - 400d]}
	bcc	LF583		; br if no overflow, overflow occurs when MAP A/D is 0x7D (125d) or about 104.84 KPA
				;  for a 2-bar MAP,	overflow when 3-bar MAP A/D is 83d (0x53), 104.3 KPA 
LF581:	ldaa	#0xFF		; else, overflow occurred, clamp calc. MAP value to 0xFF
LF583:	staa	*L003D		; save MSB as calc. MAP value (for calc. Load MAP stuff)
	ldaa	*L003F		; get the filtered MAP A/D value
	ldab	#0xFA		; #0xC8  load reg_b with 0xC8 (200d) for 2-bar, load with 0xFA (300d) for 3-bar
	mul			; (FILT_MAP_A2D * 200d or 300d), overflow DOES NOT happen here for 2-bar
	adca	#0x08		; (FILT_MAP_A2D * 200d or 300d) + 8d + carry_bit, overflow DOES NOT happen here for 2-bar
	;; check for 3-bar overflow, clamp to 0xFF if overflow (over flow occurs at 3-bar MPA value of 271KPA,
	;; 3-bar MAP A/D count of 219d (0xDB), so all BPW fuel MAP calcs would be lean from 271 KPA to 315 KPA
	ldab    #0x01		; default; assume no overflow and load the MAP_FOR_BPW_3BAR value  (fuel multiply by 1)
	stab    *L003Ax		; save the MAP_FOR_BPW_3BAR term (that is used at approx. addr. 0xD684 fuel equation)
  	bcc	LF58C		; branch if no overflow from 3-bar MAP
	staa	*L003Ax		; else, overflow occurred, save the new MAP_FOR_BPW_3BAR term for the fuel calc.
  	ldaa	#0xFF		; clamp the MAP value used for BPW calc. to 0xFF
LF58C:	staa	*L003A		; save MSB as calc. filtered MAP A/D value for injector BPW calculation
	rts			; return to caller
	;; -------------------------------------------------------	
LF58F:	staa	*L003D		; 2-bar MAP not installed, do MAP fuel calc. for 1-bar MAP sensor
	ldab	#0xBD		; load reg_b with 0xBD (189d) for 1-bar
	mul			; (FILT_MAP_A2D * 189d)
	adca	#0x15		; (FILT_MAP_A2D * 189d) + 21d + carry_bit, overflow DOES NOT happen here
	staa	*L003A		; save MSB as calc. filtered MAP A/D value for injector BPW calculation
	ldab    #0x01		; default; load the MAP_FOR_BPW_3BAR value  (multiply by 1)
	stab    *L003Ax		; save the MAP_FOR_BPW_3BAR term
	rts
	;; -------------------------------------------------------
	;; LAG Filter
	;; 
	;; New Y value is returned in reg_a and reg_b
	;; 
	;; Inputs:	reg_x = old value Y0
	;;		reg_a = input X
	;;		reg_b = filter coefficient K
	;; Output:	reg_a = Y MSB
	;;		reg_b = Y LSB
	;; 
	;; Y = Y0 + K * (X - Y0) = Y0 + K*X - K*Y0
	;; Y = new value
	;; Y0 = old value
	;; X = input
	;; K = coefficient